Zählen eines bestimmten Zeichens innerhalb einer Zelle

Mit den Formeln "ANZAHL" und "ZÄHLENWENN" lässt sich die Anzahl bestimmter Werte über mehrere Zellen hinweg ermitteln. Möchte man jedoch ein bestimmtes Zeichen innerhalb einer einzelnen Zelle zählen, benötigt das eine etwas andere Kombination von Formeln. Angenommen in Zelle "A1" steht unser Text:

ZaehlenTextfolge1

Wir möchten nun zählen, wie oft das Zeichen "e" darin vorkommt. Im untenaufgeführten Bildausschnitt wird dazu eine Hilfszelle (D1) verwendet. Die effektive Formel wird in der Zelle "D2" angewendet und ergibt im Falle des Textes "Alles Gute im Jahr 2018!" zwei. Die Formel lautet wie folgt:

=LÄNGE(A1)-LÄNGE(WECHSELN(A1;D1;""))

ZaehlenTextfolge2

Die oben genannte Formel macht folgendes: Sie zählt einerseits die Länge (Anzahl Zeichen) im Text. Mit dem Teil "WECHSELN(...)" wird innerhalb des Textes jedes "e" durch nichts ("") ersetzt und erneut die Länge (Anzahl Zeichen ohne "e") ermittelt. Die Differenz daraus ergibt demnach die Anzahl "e" innerhalb der Textfolge.

Alternativ könnte anstatt einer Hilfszelle (D1) auch einfach ein Wert eingegeben werden. Möchte man beispielsweise die Leerzeichen zählen (=4), wendet man folgende Formel an:

=LÄNGE(A1)-LÄNGE(WECHSELN(A1;" ";""))

D1 wurde hier durch " " ersetzt.

12 Gedanken zu “Zählen eines bestimmten Zeichens innerhalb einer Zelle

  1. Ich habe ein ganz ähnliches Problem - ich möchte nicht nur einen bestimmten Buchstaben in einer Zelle zählen sondern mehrer.
    Konkret geht es darum in der Zelle "I2" die Anzahl der Buchstaben F; H; M und S der Zelle "E2" zu summieren und auszugeben. Und dies wenn möglich direkt, also nicht über eine zusätzliche Hilfszelle. Und auch wichtig, es dürfen nur Grossbuchstaben berücksichtitgt werden.

    Schon jetzt vielen Dank für die Hilfe.
    Gruss Smily44

    • Hallo Smily44
      Deine Anforderung konnte ich mit der obigen Formel abdecken. Für den Grossbuchstaben "F" habe ich die Formel =LÄNGE(E2)-LÄNGE(WECHSELN(E2;"F";"")) verwendet. Um alle vier Buchstaben (F, H, M und S) zu summieren, habe ich einfach diese Formel mit jedem Buchstaben jeweils mehrmals hintereinander eingefügt und mit dem Operator "+" zusammengezählt. Hier die gesamte Formel für die Zelle I2:
      =LÄNGE(E2)-LÄNGE(WECHSELN(E2;"F";""))+LÄNGE(E2)-LÄNGE(WECHSELN(E2;"H";""))+LÄNGE(E2)-LÄNGE(WECHSELN(E2;"M";""))+LÄNGE(E2)-LÄNGE(WECHSELN(E2;"S";""))

      Dies zählt Dir die Buchstaben korrekt zusammen - und es werden nur die Grossbuchstaben berücksichtigt! Als Beispielstext habe ich folgendes verwendet:
      1.) "Hier Steht Mein Text" - ergibt 3. Beachte: Der Buchstabe H wird nur einmal gezählt, das kleingeschrieben "h" im Wort "Steht" wird nicht gezählt.
      2.) "Meine Lebensmittel Kaufe Ich Bei Migros" - ergibt 2. Nur der Grossbuchstabe "M" wird zweimal gezählt.

      Hier noch ein Screenshot dazu:
      https://excelblog.ch/media/ZeichenZaehlenAntwort.jpg

      Beste Grüsse & viel Erfolg
      Roman

  2. Hallo, ich habe im Prinzip die selbe Fragestellung wie oben dargestellt. Allerdings handelt es jetzt um ein einkopiertes langes Gedicht mit vielen Zeilen und entsprechenden Umbrüchen. Ich möchte die Anzahl eines jeden Buchstabens ermitteln. Groß und klein braucht nicht unterschieden zu werden.
    Vielen Dank vorab
    Jork

    • Hallo Jork

      Danke für Deinen Kommentar. Damit Du weisst, welcher Buchstabe wie oft vorkommt, müsstest Du eine Auflistung machen. Unten stelle ich Dir einen Link zu einer Beispiel-Datei zu:
      https://excelblog.ch/wp-content/uploads/Buchstaben-zählen.xlsx

      Darin siehst Du in Zelle "A1" den Text (das Gedicht). Nebenan habe ich alle 26 Buchstaben aufgeführt (Spalte B enthält die Grossbuchstaben, mit der Formel =KLEIN() erhalte ich nebenan jeweils den Kleinbuchstaben). In D1 setze ich dann diese Formel ein, die auf alle Buchstaben angewandt (runterkopiert) werden kann:
      =LÄNGE($A$1)-LÄNGE(WECHSELN($A$1;B1;""))+LÄNGE($A$1)-LÄNGE(WECHSELN($A$1;C1;""))

      Es ist die gleiche Formel wie im Beitrag oben, allerdings zählen wir mit dem +-Zeichen die Anzahl Gross- und Kleinbuchstaben zusammen. Nebst den Buchstaben könntest Du dies beliebig um Sonder-/Satzzeichen ergänzen - beachte dabei jedoch, dass Du nicht beide Spalten (B + C) ausgefüllt haben musst, da die Zeichen sonst doppel gezählt werden!

      Beste Grüsse
      Roman

  3. Hallo und Danke für diesen Artikel

    Ich habe ebenfalls eine ähnliche Fragestellung, suche aber nach einer Möglichkeit, eine Zeichenfolge (Text, z.B. sd.d.tld) innerhalbe einer Zelle zu zählen.
    Also wie oft kommt diese Zeichenfolge in einer Zelle vor.

    Besten Dank im Voraus, falls jemand eine Lösung dafür hat.
    Grüsse Andreas

    • Hallo Andreas

      Du kannst auch längere Zeichenfolgen zählen, ja. Hierzu können wir die eingangs erwähnte Formel wiederverwenden:
      =LÄNGE(A1)-LÄNGE(WECHSELN(A1;" ";""))

      Anstelle von " " müsstest Du Deine gewünschte Zeichenfolge einfügen; entweder mit einem Zellenbezug oder als Text innerhalb der Formel:
      =LÄNGE(A1)-LÄNGE(WECHSELN(A1;"sd.d.tld";""))

      Du wirst zunächst eine Vielzahl der Zeichenlänge von "sd.d.tld" erhalten. Um die korrekte Anzahl der Vorkommnisse zu ermitteln, werden wir das Ergebnis noch durch die Anzahl Zeichen ("=LÄNGE()") Deiner Zeichenfolge dividieren. Die finale Formel wäre demnach:
      =(LÄNGE(A1)-LÄNGE(WECHSELN(A1;"sd.d.tld";"")))/LÄNGE("sd.d.tld")

      Es wäre sicherlich sinnvoll, wenn Du anstelle von "sd.d.tld" einen Zellenbezug machst, wo Du diese Zeichenfolge hinterlegst.

      Liebe Grüsse
      Roman

  4. Hallo Roman,

    erstmal vielen Dank für diesen Artikel.

    Ich habe ebenfalls eine ähnliche Fragestellung, suche aber nach einer Möglichkeit, eine Zeichenfolge (Text, z.B. R,Mchem,M) innerhalbe einer Zelle zu zählen.
    Ich möchte eigentlich nur zählen wie viele Wörter da stehen..hier also 3. Ich habe das so angewendet wie du gesagt hast, in dem ich für jedes Wort die Formel angewendet habe. Jedoch erhalte ich immer eine 4, weil ich denke, dass das "M" doppelt gezählt wird.

    Die Formel:
    =(LÄNGE(A10)-LÄNGE(WECHSELN(A10;"Mchem";"")))/LÄNGE("Mchem")+(LÄNGE(A10)-LÄNGE(WECHSELN(A10;"R";"")))+(LÄNGE(A10)-LÄNGE(WECHSELN(A10;"M";"")))

    • Hallo Athi

      Danke Deinen Kommentar.

      Wäre es eine Alternative, dass Du einfach die Anzahl Komma-Zeichen zählst (und +1 addierst)?

      Beste Grüsse
      Roman

  5. Hi,
    ich habe eine ähnliche Frage. Ich möchte in einer ganzen Spalte einer Tabelle nach einer Zeichenkette suchen (z.B.: "abc"). Dabei soll auch gezählt werden, wenn neben "abc" noch etwas anderes in der Zelle steht

    Viele Grüße
    Elias

    • Hallo Elias

      Du kannst mit einer Hilfsspalte neben Deinen Inhalten ermitteln, ob die Zeichenkette (z.B. "abc") darin enthalten ist. Das funktioniert mit der obigen Formel, vereinfacht dargestellt:

      Deine Inhalte sind in der Spalte A. Prüfe in der Spalte B (oder sonstwo nebenan) mit der nachfolgenden Formel, ob "abc" gefunden wird. Die Formel für Zeile 2 lautet:
      =LÄNGE(A2)-LÄNGE(WECHSELN(A2;"abc";""))

      für Zeile 3 wäre sie selbstverständlich:
      =LÄNGE(A3)-LÄNGE(WECHSELN(A3;"abc";""))

      So wird Dir die Zahl 3 angegeben (Länge von "abc") - sowohl für "abc" wie auch andere Texte wie "abcdefg" oder "xyzabc".
      Natürlich könntest Du hier zusätzlich mit einer "WENN"-Formel diverse andere Ergebnisse anzeigen lassen.

      Falls Du über die gesamte Spalte die Anzahl Vorkommnisse von "abc" ermitteln möchtest, hilft die "ZÄHLENWENN"-Formel:
      =ZÄHLENWENN(A:A;"*abc*")

      Liebe Grüsse
      Roman

  6. Hallo, glaub ich hab eine ähnliche frage… ich habe viele Preise in einigen Zellen zb: 4,3 nur dieses format….und ich muss die ziffern zählen… wieviele 1er, 2er …etc

Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert

Diese Website verwendet Akismet, um Spam zu reduzieren. Erfahre mehr darüber, wie deine Kommentardaten verarbeitet werden.