Format einer Zelle auslesen und Zeile einfärben

Ein vielbesuchter Beitrag hier auf Excelblog.ch illustriert, wie sich eine ganze Zeile mit bedingten Formatierungen einfärben lässt (siehe Ganze Zeile einfärben (bedingte Formatierung)). Darin wird dargestellt, wie aufgrund einer Zellen-Angabe eine gesamte Zeile farbig hervorgehoben werden kann. Dabei wird meist nach einem bestimmten Text gesucht. In diesem Beitrag stelle ich Dir eine weitere Möglichkeit dar, um auf das Format einer Zelle einzugehen und eine entsprechende Einfärbung zu bewirken.

Für das Einlesen des aktuellen Zellenformats verwenden wir die Formel "ZELLE". In einem anderen Post wurde diese Formel bereits verwendet, um den aktuellen Tabellenblatt-Namen auszulesen (Mittels Formel den Tabellenblatt-Name ausgeben). Gehen wir zuerst auf die Formel im Einzelnen ein, anhand eines Beispiels:

Füge in der Zelle "A1" einen beliebigen Wert ein, zum Beispiel ein Datum wie 17.05.2022. Füge dann die untenstehende Formel in eine beliebige Zelle ein (z.B. "A2"), um das Format der Zelle "A1" auszulesen:

=ZELLE("format";A1)

Falls in "A1" tatsächlich ein Datum steht, erhältst Du "D1" als Formel-Resultat. Ändere nun das Format der Zelle "A1", beispielsweise zu Standard. Beachte: Das Formel-Resultat verändert sich nicht umgehend (eine technische Anmerkung: Obschon unter Formeln die Berechnungsoptionen auf "Automatisch" eingestellt sind). Aktualisiere die "ZELLE"-Formel erneut (gehe dafür in den "Bearbeitungsmodus" und bestätige die Formel mit der Enter-Taste erneut. Nun wird Dir für die "Standard-Formatierung" ein "S" ausgegeben.

Weitere Format-Optionen und Formel-Resultate

Schauen wir uns einige weitere Optionen an, teste gerne auch eigene Fälle und aktualisiere jeweils die "ZELLE"-Formel, um das Resultat zu sehen:

Formel ZELLE format

Beachte ein Muster bei Zahlen oder Prozentwerten und deren Dezimalstellen: Der Zähler erhöht sich jeweils, wobei "P" für Prozent (percentage) steht; "F" repräsentatiert "figure" (Engl.: Zahl).

Anwendung zur Einfärbung einer Zelle oder gesamten Zeile

Mit diesen Vorkenntnissen können wir nun eine bedingte Formatierung bei der Zelle selbst hinterlegen, in unserem Beispiel die Zelle "A1". Gehe dazu via "Start" → "Bedingte Formatierung" auf "Neue Regel...". Wähle dort die unterste Option "Formel zur Ermittlung der zu formatierenden Zelle verwenden" und füge die nachfolgende Formel ein:

=ZELLE("format";A1)="D1"

Wir wissen ja, dass wir im Falle eines Datums (17.05.2022) "D1" als Formel-Resultat zurückerhalten. Wir prüfen demnach, ob die Zelle A1 entsprechend formatiert ist und färben die Zelle daraufhin grün ein:

Formatierungsregel ZELLE Format

Um eine gesamte Zeile einzufärben, basierend auf der Angabe in Spalte "A", müsstest Du die Formel leicht anpassen, mit einem Dollarzeichen vor "A1":

=ZELLE("format";$A1)="D1"

Wir fixieren damit nur die Spalte, nicht die Zeile (da wir wahrscheinlich die bedingte Formatierung auf einen grösseren Bereich anwenden möchten; zum Beispiel von A1 bis F100. Setze dadurch in den bedingten Formatierungen unter "Regeln verwalten" den Bereich "=$A$1:$F$100" bei "Wird angewendet auf":

Formatierungsregel angewendet auf

Du kannst unter "Regel bearbeiten" Deine Formel jederzeit anpassen (z.B. auf "P2" für den gesuchten Prozentwert im Format "85.00%") sowie die Formatierung (Farbe, Schriftart, etc.) setzen.

Beachte: Wir haben oben erwähnt, dass die Formel bei einer Änderung der Formatierung erneut eingegeben werden muss. Das ist bei der bedingten Formatierung nicht der Fall. Solltest Du also einen Wert und dessen Formatierung anpassen (z.B. von einem Datum in einen Prozentwert umwandeln), wird umgehend die (bedingte) Formatierung zur Anwendung kommen.

Dateipfad mit einer Formel darstellen

Den Pfad einer Datei darzustellen, kennen die meisten womöglich mittels der Kopf- und Fusszeilen-Funktion. Ich zeige Dir in diesem Beitrag auf, wie Du dies auch mittels einer Formel machen kannst, damit Du den Pfad der aktuellen Datei in einer beliebigen Zelle in Excel ausgeben kannst.

Kopf- und Fusszeile

Bekannter ist die Vorgehensweise, den aktuellen Dateipfad in die Kopf- oder Fusszeile zu integrieren. Dazu gibt es eine vorgefertigte Auswahlmöglichkeit in den Kopf- und Fusszeilentools, die folgendes Resultat liefert:

dateipfadkopfzeile

Dies bedeutet jedoch, dass Du den Pfad immer an einer bestimmten Stelle (eben zu oberst oder zu unterst im Dokument) angezeigt haben wirst. Im nächsten Abschnitt findest Du, mithilfe welcher Formel Du diese Information in jeder beliebigen Zelle hinterlegen kannst!

Die Formel =ZELLE

Wie die Überschrift bereits andeutet, bietet die Formel "=ZELLE" die entsprechende Möglichkeit. Wendet man die Formel an, kommt eine Auswahlmöglichkeit:

dateipfadzelle

Wähle hier "dateiname" und schliesse die Formel ab. Vollständig in einer beliebigen Zelle steht also:

=ZELLE("dateiname")

Und das Resultat ist der Pfad (inklusive Dateiname/Tabellenblatt). Beachte: Es wird nur etwas angezeigt, wenn Deine Excel-Datei auch einen Speicherort hat. Öffnest Du einfach die Applikation und versuchst dies aus (Mappe1), wird es nicht funktionieren. Speichere die Datei ab, aktualisiere die Formel und Du erhältst den Output (bspw.: "C:\Users\Roman\Desktop\[MeineDatei.xlsx]Tabelle1". Möchtest Du nun NUR den Dateipfad angezeigt bekommen, braucht es einige Ergänzungen. Die fertige Formel lautet:

=LINKS(ZELLE("dateiname");SUCHEN("[";ZELLE("dateiname"))-2)

Dies ergibt: "C:\Users\Roman\Desktop". Wir suchen also einerseits nach dem Zeichen "[" - dieses steht für den Dateinamen. Vom gesamten Konstrukt nehmen wir alle Zeichen von links bis zu dieser eckigen Klammer (abzüglich 2: Eben die Klammer und den letzten Backslash "\").

P.S.: Hängst Du hinter "dateiname" noch einen Bezug in eine andere Datei/Zelle, dann wird Dir davon der Pfad/Dateiname angezeigt!

Mittels Formel den Tabellenblatt-Name ausgeben

Mit einer Zusammensetzung von diversen Formeln kann der Name des aktuellen Tabellenblatts ausgegeben werden. Die komplette Formel lautet:

=TEIL(ZELLE("dateiname");SUCHEN("]";ZELLE("dateiname"))+1;100)

Das Ergebnis dieser Formel ist bei meiner Datei: "MeinTabellenblatt". [Beachte, dass dies nur bei bereits abgespeicherten Dateien funktioniert.]

Die drei verschiedenen verwendeten Formeln bewirken folgendes; beginnen wir mit "=ZELLE":

In dieser Funktion wird zuerst nach dem "Infotyp" gefragt - wir wollen, dass der Dateiname der aktiven Zelle ausgegeben wird. Das Ergebnis: C:\....\...\[MeineDatei.xlsx]MeinTabellenblatt. Nicht zwingend ist eine "Referenz" nach dem Infotyp als zweites Argument innerhalb der Formel. Man könnte da auf eine andere Zelle verweisen; auch auf ein anderes Tabellenblatt - und könnte so schlussendlich mit leichtem Modifizieren der obigen Formel den Namen eines anderen Tabellenblattes ausgeben lassen.

Die Formel "=SUCHEN" haben wir im Beitrag "Textfragmente aus einer Zelle ziehen" genauer betrachtet: Es wird damit die Position des Suchtextes (in unserem Beispiel die eckige Klammer "]" nach dem Dateinamen) ausgemacht, ab welcher (+1) die "=TEIL"-Funktion einen entsprechenden Text ausgibt. Die 100 zum Schluss der obigen Formel ist lediglich eingebaut, dass bestimmt genügend Zeichen ausgegeben werden (also ein Tabellenname mit bis zu 100 Zeichen). Diese hohe Zahl ist unkritisch, da keine ungewünschten Leerzeichen an den Text angefügt werden.